SYSTEM VARIABLES
PROG : 16509
D-FILE: 18654
VARS : 19447
E-LINE: 19448
STKBOT: 19457
STKEND: 19457
LEGEND
[A] means INVERSE A
{A} means GRAPHICS A
PRINT means treat as KEYWORD P
PROGRAM LISTING
10 REM **STUD**SLR/1984*******
20 LET M=100
30 LET Y=100
31 DIM C(2)
32 DIM S(2)
40 DIM B(2)
50 PRINT " STUD 1 POKER"
60 PRINT ,,,,,," THE OBJECT OF STUD 1 IS TO BET MONEY TRYING TO KEEP FROMBUSTING.THE WINNER OF EACH HAND IS THE ONE WITH THE HIGHEST FACEVALUE. HAPPY BETTING."
70 PRINT ,,"PRESS ANY KEY TO CONTINUE"
80 PAUSE 4E4
82 IF INKEY$<>"" THEN GOTO 82
85 FOR A=1 TO 2
90 LET C(A)=INT (13*RND+1)
100 LET S(A)=INT (4*RND+1)
105 NEXT A
110 CLS
120 PRINT "WHAT IS YOUR BET (1-";Y;")? ";
130 LET L$=""
140 IF INKEY$="" THEN GOTO 140
142 LET B$=INKEY$
144 IF B$=CHR$ 118 THEN GOTO 200
146 IF B$<"0" OR B$>"9" THEN GOSUB 190
150 LET L$=L$+B$
160 PRINT B$;
170 IF INKEY$<>"" THEN GOTO 170
180 GOTO 140
190 FOR A=1 TO 4
192 FAST
194 SLOW
196 NEXT A
198 GOTO 170
200 IF L$="" THEN GOTO 190
205 LET U=VAL L$
206 IF U=0 THEN GOTO 110
210 IF U>Y THEN LET U=Y
220 LET B(1)=U
230 LET U=INT (M*RND+1)
240 IF U<B(1) THEN LET U=B(1)
245 IF U>M THEN LET U=M
250 LET B(2)=U
260 PRINT TAB 0;"OK, OUT OF ";M;" I BET ";B(2);"."
270 PRINT ,,,,"NOW WE ARE READY, SO LET US DEALTHE CARDS. HERE IS YOURS:"
280 FOR A=1 TO 2
290 IF A=2 THEN PRINT "MINE IS:"
300 GOSUB 1000
310 NEXT A
320 IF H1=H2 THEN GOTO 400
330 IF H1>H2 THEN GOTO 350
340 PRINT ,,"HA, MY CARD IS HIGHER, I WIN."
341 LET Y=Y-B(1)
342 LET M=M+B(2)
343 PAUSE 500
344 IF Y<=0 THEN GOTO 500
345 GOTO 70
350 PRINT ,,"DRATS, YOUR CARD BEATS MINE."
360 LET Y=Y+B(1)
370 LET M=M-B(2)
380 PAUSE 500
390 IF M<=0 THEN GOTO 580
395 GOTO 70
400 PRINT ,,"WHEW, WE TIED. NO LOSES OR WINS."
410 GOTO 70
500 CLS
510 PRINT ,,,,"WOW YOU ARE BROKE. THAT MEANS THAT I WIN THE GAME***"
520 PRINT ,,,,"PLAY AGAIN?"
530 IF INKEY$="" THEN GOTO 530
540 IF INKEY$="N" THEN STOP
550 IF INKEY$="Y" THEN CLS
560 IF INKEY$="Y" THEN RUN
570 GOTO 530
580 CLS
590 PRINT ,,,,"UH, OH. I AM OUT OF MONEY. LOOKS LIKE YOU WIN***"
600 PRINT ,,,,"YOU HAVE ";Y;" POINTS LEFT."
610 GOTO 520
1000 LET A$=("*" AND S(A)=1)+("?" AND S(A)=2)+("+" AND S(A)=3)+("$" AND S(A)=4)
1010 LET L$=" "+STR$ C(A)
1020 IF C(A)=1 THEN LET L$=" ACE"
1030 IF C(A)=11 THEN LET L$="JACK"
1040 IF C(A)=12 THEN LET L$="QUEEN"
1050 IF C(A)=13 THEN LET L$="KING"
1060 PRINT "{8}{7}{7}{7}{7}{7}{5}";TAB 0;"{8}";A$;" ";"{5}";TAB 0;"{8}";L$;TAB 6;"{5}";TAB 0;"{8} ";A$;"{5}";TAB 0;"{8}{6}{6}{6}{6}{6}{5}"
1070 LET H1=C(1)
1080 LET H2=C(2)
1090 RETURN